import godking.word
var word = godking.word();

//添加图片
import inet.http
var picdata = inet.http.get("http://www.chengxu.online/images/banner.gif");
word.addParagraph(2).addPicture( picdata/*图片文件*/,20/*厘米宽度*/,2.5/*厘米高度*/);

//添加简单段落
word.addParagraph().addText("我是第一段文本");

//添加表格
var tb1 = word.addTable(3/*行数*/,3/*列数*/);
tb1.setTable({
	{1,2,3}
	{4,5,6}
	{7,8,9}
})

//修改表格内容
var cell = tb1.getRow(1).getCell(1);
cell.setText("替换文本");

var cell = tb1.getRow(1).getCell(2);
cell.addText("追加文本");

tb1.getRow(1).getCell(3).clear();

tb1.setCellText(2/*行号*/,2/*列号*/,"我是直接修改过的文本"/*文本*/,/*设置表*/)

//插入行
tb1.insertRow(2,{"插入1","插入2","插入3"})

//加入行
tb1.addRow({"插入4","插入5","插入6"})

//设置一个带格式的单元格
tb1.setCellText(tb1.getRowCount()/*行号*/,2/*列号*/,"我是带格式的文本"/*文本*/,{
	/*设置单元格文本。本参数为单元格段落及文本默认设置。
	  以下属性若设为 null 则使用 setConfig() 函数中设置的默认设置*/
	align=2;	/*水平对齐方式：1、左对齐(默认)；2、居中；3、右对齐；4、两端对齐；6、分散对齐*/
	indent=0;	/*首行缩进，单位：厘米*/
	spacingline=0;	/*行间距*/
	linerule=0;		/*间距模式：1、行距倍数；2、固定值(厘米)；3、最小值(厘米)*/
	before=0;	/*段前距离，单位：厘米*/
	after=0;	/*段后距离，单位：厘米*/
	fontname="黑体";	/*字体名称*/
	fontsize=20;	/*文字大小*/
	fontcolor="0000FF";	/*文字颜色，RGB模式，支持格式：0xRRGGBB、"0xRRGGBB"、"#RRGGBB"、"RRGGBB"*/
	bold=true;			/*是否粗体*/
	italic=true;		/*是否斜体*/
	underline=true;	/*是否下划线*/
})

//在单元格原内容后面插入图片
var row = tb1.getRow( tb1.getRowCount()/*行序号*/);
var cell = row.getCell(3 /*单元格序号*/);
//在原内容的后面，再添加一个段落，并在该段落中添加文本和图片
var run = cell.addParagraph(); 
//paragraph 和 run 支持连续赋值
run.addText("这是图片：").addPicture( picdata/*图片文件*/,10/*厘米宽度*/,1.2/*厘米高度*/);

//设置行高
for(i=1,tb1.getRowCount(),1){
	tb1.getRow(i /*行序号*/).setHeight(1);
}

//添加带格式的段落，居中对齐
var g = word.addParagraph(2/*对齐*/,/*行间距*/,/*模式*/,/*段前*/,/*段后*/,/*缩进*/,/*文本*/,"黑体"/*字体*/,20/*大小*/,0xFF0000/*RGB色*/,true/*粗体*/,true/*斜体*/,true/*下划线*/);
g.addText("我是本段文本的第1个run，")
g.addReturn(); //添加换行
g.addText('我是本段文本的第2个run，\n'); //自带换行
g.addText("我是本段文本的第3个run，") 
g.addText("我是本段文本的第4个run。")

//添加空段落
word.addParagraph();

//添加简单段落，右对齐
word.addParagraph(3).addText("我是第二段文本！我只有一个run。")

//设置A4纸张横向
word.setPaperSize(29,21);

//保存文件
word.save("d:\test.docx"/*文件名称*/);
word.close();

import process
process.execute("d:\test.docx")